كيفية معرفة السيريال نمبر ويندوز 11

 

 

 كيفية معرفة السيريال نمبر ويندوز 11

 

يبحث الكثير حول معرفه سيريال الخاص بالنسخه التي يستخدمها غالبا تاتي اجهزه مثبت عليها مسبقه انظمه ويندوز ومفعله ولا يأتي السيريال الخاص بها بشكل منفرد وبعض الاخر من اجهزه لابتوب ياتي السيريال مطبوع علي الجهاز كما في الصوره اسفل

 

 

 

لذا يجب التأكد من هذا قبل استخدام البرنامج تسهيلا عليك الأمر , تكمله للموضوع يوجد حل اخر هو تثبيت برنامج من خلاله يقوم بعرض سيريال الخاص بنسخه بشكل مباشر ,

 

 

تحتوي كل نسخة مفعلة وأصلية من ويندوز على سيريال فريد مكون من 25 حرفًا. إذا احتجت في أي وقت لإعادة تثبيت ويندوز على نفس الكمبيوتر أو كمبيوتر آخر، ستحتاج اولًا إلى معرفة هذا السيريال لاستعادة واستخدام النسخة الأصلية من ويندوز مرة أخرى. لكن المشكلة هنا أن معظم المستخدمين لا يعرفون السيريال المستخدم لتفعيل ويندوز على أجهزتهم، وهذا في الغالب بسبب شرائهم لابتوب مثبت عليه نسخة مفعلة مسبقًا من ويندوز.

 

 

ومع ذلك، فلا تحتاج إلى شراء سيريال جديد من مايكروسوفت لإعادة تفعيل نسخة الويندوز لديك مرة أخرى، فهناك أكثر من طريقة للكشف عن السيريال الحالي بسهولة. واحدة من هذه الطرق هي النظر إلى الملصق التابع لمايكروسوفت والمدون عليه السيريال كما هو موضح في الصورة اعلاه. ولكن دعني أخبرك كل الشركات المصنعة الآن لم تعد تضيف هذا الملصق لأجهزتها بغية منع السرقة أو الاستخدام غير المصرح به. لذا، فالطرق المستعرضة أدناه تظهر السيريال من خلال نظام ويندوز نفسه، إليك كيف؟.

 

الطريقة الاولى انشاء ملف vbs 

في البداية ستقوم بانشاء مستند txt جديد وقم بنسخ الكود اسفله ولصقه داخله

 

كود:

Option Explicit
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
Save ProductData
End If
'Convert binary to chars
Function ConvertToKey(Key)
Const KeyOffset = 52
Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
'Check if OS is Windows 8
isWin8 = (Key(66) \ 6) And 1
Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
i = 24
Maps = "BCDFGHJKMPQRTVWXY2346789"
Do
Current= 0
j = 14
Do
Current = Current* 256
Current = Key(j + KeyOffset) + Current
Key(j + KeyOffset) = (Current \ 24)
Current=Current Mod 24
j = j -1
Loop While j >= 0
i = i -1
KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
Last = Current
Loop While i >= 0

If (isWin8 = 1) Then
keypart1 = Mid(KeyOutput, 2, Last)
insert = "N"
KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
If Last = 0 Then KeyOutput = insert & KeyOutput
End If
ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
End Function
'Save data to a file
Function Save(Data)
Dim fso, fName, txt,objshell,UserName
Set objshell = CreateObject("wscript.shell")
'Get current user name
UserName = objshell.ExpandEnvironmentStrings("%UserName%")
'Create a text file on desktop
fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
Set fso = CreateObject("Scripting.FileSystemObject")
Set txt = fso.CreateTextFile(fName)
txt.Writeline Data
txt.Close
End Function

 

 

بعد لصق الكود داخل المفكرة توجة الى "File" من ثم "Save as" حدد مكان الحفظ, مع اعادة تسمية الملف سميه ماشئت, بشرط ان يكون بهذا الامتداد "vbs"

الان بعد الانتهاء ستحصل على ملف vbs كما تراه في الصورة اسفله, فقط دوبل كليك لفتحه وعرض سيريال نمبر الخاص بالويندوز 11

الطريقة الثانية من الريجستري 

افتح نافذة Run بالضغط على مفتاحي Win + R واخل هذا الامر regedit ثم Ok

ستفتح معك نافذة الريجستري واتبع المسار التالي:

 HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform

HKEY_LOCAL_MACHINE
ثم
SOFTWARE
ثم
Microsoft
ثم
Windows NT
ثم
CurrentVersion
ثم
SoftwareProtectionPlatform

 

بعد وصولك الى مجلد "SoftwareProtectionPlatform" قف عليه وفي الجهة اليمنى من الصفحة ابحث عن "BackupPreduct" الى جانبه السريال نمبر للويندوز

توجد طرق اخرى اعرض سيريال نمبر للويندوز لكن هذه اسهلها واشهرها على الاطلاق

انتهى الشرح بالتوفيق للجميع